Get a Grip Tennis by Wilson/Get a Grip Tennis by Wilson.iso/pc/wilson.dxr/Internal_52_General Button Control (for QT scrub).ls

Text File | 2003-08-12 | 3.7 KB | 98 lines

property pMySprite, pMyMember, pCurrentSpriteCursor, pMouseOver, pMouseDown, pMouseEnterSound, pMouseDownSound, pEnterSoundFlag, pDownSoundFlag, pSoundChannel, pCursorFlag, pCursorMO, pCursorMD, pMarker, pProcessMarker, pMUScript, pProcessRollovers

on beginSprite me
  pMySprite = me.spriteNum
  pMyMember = sprite(pMySprite).member
  pCurrentSpriteCursor = -1
end

on endSprite me
  cursor(pCurrentSpriteCursor)
end

on mouseEnter me
  if pProcessRollovers then
    sprite(pMySprite).member = pMouseOver
  end if
  if pEnterSoundFlag then
    puppetSound(pSoundChannel, pMouseEnterSound)
  end if
  if pCursorFlag and (the mouseDown = 0) then
    cursor(pCursorMO)
  end if
end

on mouseLeave me
  if the mouseDown = 0 then
    cursor(pCurrentSpriteCursor)
    if pProcessRollovers then
      sprite(pMySprite).member = pMyMember
    end if
  end if
end

on mouseDown me
  if pProcessRollovers then
    sprite(pMySprite).member = pMouseDown
  end if
  if pDownSoundFlag then
    puppetSound(pSoundChannel, pMouseDownSound)
  end if
  if pCursorFlag then
    cursor(pCursorMD)
  end if
end

on mouseUp me
  if pCursorFlag and pProcessMarker then
    sprite(pMySprite).cursor = pCurrentSpriteCursor
    go(pMarker)
  else
    if pProcessMarker then
      go(pMarker)
    else
      if pCursorFlag then
        cursor(pCursorMO)
      end if
    end if
  end if
  do(pMUScript)
end

on mouseUpOutSide me
  cursor(pCurrentSpriteCursor)
end

on getPropertyDescriptionList
  pdlist = [:]
  thisMember = sprite(the currentSpriteNum).member
  thisMemberNum = thisMember.number
  overMem = thisMember
  downMem = thisMember
  if member(thisMemberNum + 1).type = #bitmap then
    overMem = member(thisMemberNum + 1)
  end if
  if member(thisMemberNum + 2).type = #bitmap then
    downMem = member(thisMemberNum + 2)
  end if
  addProp(pdlist, #pProcessRollovers, [#comment: "process rollovers: ", #format: #boolean, #default: 1])
  addProp(pdlist, #pMouseOver, [#comment: "mouseOver image: ", #format: #bitmap, #default: overMem])
  addProp(pdlist, #pMouseDown, [#comment: "mouseDown image: ", #format: #bitmap, #default: downMem])
  addProp(pdlist, #pProcessMarker, [#comment: "process jump to marker: ", #format: #boolean, #default: 1])
  addProp(pdlist, #pMarker, [#comment: "which marker on mouseUp: ", #format: #marker, #default: #next])
  addProp(pdlist, #pEnterSoundFlag, [#comment: "play mouseEnter sound: ", #format: #boolean, #default: 0])
  addProp(pdlist, #pMouseEnterSound, [#comment: "which sound: ", #format: #sound, #default: #none])
  addProp(pdlist, #pDownSoundFlag, [#comment: "play mouseDown sound: ", #format: #boolean, #default: 0])
  addProp(pdlist, #pMouseDownSound, [#comment: "which sound: ", #format: #sound, #default: #none])
  addProp(pdlist, #pSoundChannel, [#comment: "sound channel: ", #format: #integer, #default: 2, #range: [#min: 1, #max: 8]])
  addProp(pdlist, #pCursorFlag, [#comment: "change cursor: ", #format: #boolean, #default: 1])
  addProp(pdlist, #pCursorMO, [#comment: "mouseOver cursor: ", #format: #cursor, #default: 280])
  addProp(pdlist, #pCursorMD, [#comment: "mouseDown cursor: ", #format: #cursor, #default: 280])
  addProp(pdlist, #pMUScript, [#comment: "mouseUp command: ", #format: #string, #default: EMPTY])
  return pdlist
end

on getBehaviorDescription
  return "A nice general button control.  Developer has the ability to set mouseOver and mouseDown states for the button, which marker to go to, whether or not to play a sound on mouseEnter and/or mouseDown, and if the cursor should change on mouseOver and mouseDown." & RETURN & RETURN & "Hilite states must be bitmaps (not SWFs)." & RETURN & "Sounds must be internal (not SWAs)." & RETURN & "Cursors must be D7+ cursors (not custom)."
end